#                                               -*- Autoconf -*-

# Process this file with autoconf to produce a configure script.

AC_PREREQ([2.63])

AC_INIT([dss11-websetup], [0.25.0], [jin@dev.digitalstrom.org])

AC_CONFIG_AUX_DIR(configure_aux)

AM_INIT_AUTOMAKE([1.10 -Wall])

BUILD_TYPE="release"

EXT_ALL="ext-all"

EXT_BASE="ext-base"

AC_ARG_ENABLE(

    [debug],

    [

        AC_HELP_STRING([--enable-debug],

                       [build debug version (default: release)])

    ],

    [

        case "${enableval}" in

            yes) BUILD_TYPE="debug" ;;

            no)  BUILD_TYPE="release" ;;

            *)   AC_MSG_ERROR([bad value ${enableval} for --enable-debug]) ;;

        esac

    ],

    [

        BUILD_TYPE="release"

    ]

)

AC_ARG_ENABLE(

    [sdcard],

    [

        AC_HELP_STRING([--enable-sdcard],

                       [make UI SD-card aware (default: disabled)])

    ],

    [

        case "${enableval}" in

            yes) SDCARD="true" ;;

            no)  SDCARD="false" ;;

            *)   AC_MSG_ERROR([bad value ${enableval} for --enable-sdcard]) ;;

        esac

    ],

    [

        SDCARD="false"

    ]

)

AC_SUBST(SDCARD)

AC_ARG_ENABLE(

    [reboot-after-update],

    [

        AC_HELP_STRING([--enable-reboot-after-update],

                       [reboot after updating system (default: disabled)])

    ],

    [

        case "${enableval}" in

            yes) NEED_REBOOT=1 ;;

            no)  NEED_REBOOT=0 ;;

            *)   AC_MSG_ERROR([bad value ${enableval} for --enable-reboot-after-update]) ;;

        esac

    ],

    [

        NEED_REBOOT=0

    ]

)

AC_SUBST(NEED_REBOOT)

AC_LANG_C

AC_HEADER_STDC

JSMIN_TOOL=

if test "x$BUILD_TYPE" = "xrelease"; then

    AC_PATH_PROG(jsmin, jsmin, no)

    if (test "x$jsmin" = xno); then

        AC_MSG_NOTICE([jsmin utility not found in PATH, will build one myself])

    else

        AC_MSG_NOTICE([Will use $jsmin to minimize the js sources])

        JSMIN_TOOL="$jsmin"

    fi

    AC_SUBST(JSMIN_TOOL)

    if test -z "$JSMIN"; then

        AC_PROG_CC

        AC_CHECK_HEADERS([stdlib.h],

                         [],

                         [AC_MSG_ERROR(required header not found)])

    fi

else

    EXT_ALL="ext-all-debug"

    EXT_BASE="ext-base-debug"

    AC_PATH_PROG(cat, cat, no)

    if (test "x$cat" = xno); then

        AC_MSG_ERROR([Please install the cat command line utility])

    fi

    CAT="$cat"

    AC_SUBST(CAT)

fi

PO2JSON_TOOL=

AC_PATH_PROG(po2json, po2json, no)

if (test "x$po2json" = xno); then

    AC_MSG_NOTICE([po2json utility not found in PATH, will build one myself])

else

    AC_MSG_NOTICE([Will use $po2json to generate the JSON language files])

    PO2JSON_TOOL="$po2json"

fi

AC_SUBST(PO2JSON_TOOL)

if test -z "$PO2JSON"; then

    AC_PROG_CXX

    AC_LANG(C++)

    AC_CHECK_HEADERS([string fstream iostream],

                     [],

                     [AC_MSG_ERROR(required header not found)])

fi

AM_CONDITIONAL(MINIMIZE, test "x$BUILD_TYPE" = "xrelease")

AM_CONDITIONAL(COMPILE_JSMIN, test "x$JSMIN_TOOL" = "x")

AM_CONDITIONAL(COMPILE_PO2JSON, test "x$PO2JSON_TOOL" = "x")

AC_SUBST(EXT_ALL)

AC_SUBST(EXT_BASE)

AC_PATH_PROG(sprocketize, sprocketize, no)

AC_PATH_PROG(yoke, yoke, no)

if (test "x$sprocketize" = "xno") && (test "x$yoke" = "xno"); then

    AC_MSG_NOTICE([Could not find sprocketize or yoke utilities!])

    AC_MSG_NOTICE([Visit http://getsprockets.org/installation_and_usage])

    AC_MSG_NOTICE([Visit http://blog.angeloff.name/post/3465035915/yoke-a-drop-in-quick-and-dirty-alternative-to])

    AC_MSG_ERROR([Please install either the sprocketize or yoke command line utility, this is requierd to prepare the js sources!])

fi

JSUTILITY="$sprocketize"

JSPARAM="-C"

JSPATH=""

if (test "x$JSUTILITY" = "xno"); then

    JSUTILITY="$yoke"

    JSPARAM="-I"

    JSPATH="./www/js/dss11/separated_js/"

fi

AC_SUBST(JSUTILITY)

AC_SUBST(JSPARAM)

AC_SUBST(JSPATH)

AC_PATH_PROG(sed, sed, no)

if (test "x$sed" = xno); then

    AC_MSG_ERROR([Please install the sed command line utility])

fi

SED="$sed"

AC_SUBST(SED)

AC_CONFIG_FILES([

            Makefile

            www/index.html

            www/cgi-bin/prodinfo.hs

            www/js/dss11/separated_js/generated/config.js

            scripts/doupdate.sh

        ])

AC_OUTPUT